added st config

.config/st/PKGBUILD

@@ -0,0 +1,53 @@
+pkgname=st
+pkgver=0.8.2
+pkgrel=2
+pkgdesc='A simple virtual terminal emulator for X.'
+arch=('i686' 'x86_64' 'armv7h')
+license=('MIT')
+depends=('libxft' 'libxext' 'xorg-fonts-misc')
+makedepends=('ncurses')
+url="http://st.suckless.org"
+source=(
+    http://dl.suckless.org/st/$pkgname-$pkgver.tar.gz
+    config.h
+    st.desktop
+    https://st.suckless.org/patches/clipboard/st-clipboard-$pkgver.diff
+    https://st.suckless.org/patches/scrollback/st-scrollback-$pkgver.diff
+	https://st.suckless.org/patches/alpha/st-alpha-$pkgver.diff
+)
+
+sha256sums=(
+    'aeb74e10aa11ed364e1bcc635a81a523119093e63befd2f231f8b0705b15bf35'
+    '3593c7abe933772398633c884bd45a397cb031f9ae4c5dcd0cd29cb94b1d51fa'
+    '6ddc5e9df00e8c915b85a0cddf35d30a3a50ee754b2cd4b74b74fea3ce0760c0'
+    '7be1a09831f13361f5659aaad55110bde99b25c8ba826c11d1d7fcec21f32945'
+    '9c5aedce2ff191437bdb78aa70894c3c91a47e1be48465286f42d046677fd166'
+	'9c5b4b4f23de80de78ca5ec3739dc6ce5e7f72666186cf4a9c6b614ac90fb285'
+)
+
+prepare() {
+  # user is supposed to maintain config.h him/herself
+  cp $srcdir/config.h $srcdir/$pkgname-$pkgver/config.h
+  cp $srcdir/$pkgname.desktop $srcdir/$pkgname-$pkgver/$pkgname.desktop
+
+  cd $srcdir/$pkgname-$pkgver
+  patch -i $srcdir/st-clipboard-$pkgver.diff
+  patch -i $srcdir/st-scrollback-$pkgver.diff
+  patch -i $srcdir/st-alpha-$pkgver.diff
+}
+
+build() {
+  cd $srcdir/$pkgname-$pkgver
+  make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11
+}
+
+package() {
+  cd $srcdir/$pkgname-$pkgver
+  make PREFIX=/usr DESTDIR="$pkgdir" TERMINFO="$pkgdir/usr/share/terminfo" install
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+  install -Dm644 README "$pkgdir/usr/share/doc/$pkgname/README"
+  install -Dm644 $pkgname.desktop "$pkgdir/usr/share/applications/$pkgname.desktop"
+  
+  # remove to avoid conflict with ncurses
+  rm "${pkgdir}/usr/share/terminfo/s/st" "${pkgdir}/usr/share/terminfo/s/st-256color" 
+}